%periods 100;
var c, h, lam, w, r, yy, xx,k,a,g;
varexo e,u;
parameters alp, delt, bet, sig, mu, ra,  rg , as, gsy, yy0,k0,c0,h0,xx0,r0,w0,lam0,gs;
alp  = 0.35;
delt = 0.025;
bet	= 0.99;
sig	= 1.500;
mu 	= 0.300;
ra	= 0.9500;
rg	= 0.97;
as  = 1;
gsy  = 0.20;


% Initial guesses for the steady state values
yy0=1;
k0=1.5; 				%capital
c0=0.8;				    %consumption
h0=0.3; 				%work
xx0=0.3; 				%investment
r0=0.04;				%interest rate
w0=2; 				    %wage
lam0=.58;

x0=[yy0;c0;k0;h0;xx0;r0;w0;lam0]; 	
sol=fcsolve('rbc_steady',x0,[]);			% Call the function 'hd_steady'

ys= sol(1);  
cs= sol(2);  
ks= sol(3);  
hs= sol(4);  
xxs= sol(5); 
rs= sol(6);  
ws= sol(7);
lams= sol(8);
gs = gsy*ys;

model;
exp(k)-exp(xx)-(1-delt)*exp(k(-1))=0; 
a-(1-ra)*log(as)-ra*a(-1)-e=0;
g-(1-rg)*log(gs)-rg*g(-1)-u=0;
(exp(c)^mu*(1-exp(h))^(1-mu))^(1-sig)*mu/exp(c)-exp(lam)=0;
-(exp(c)^mu*(1-exp(h))^(1-mu))^(1-sig)*(1-mu)/(1-exp(h))+exp(lam)*exp(w)=0;
exp(lam)-bet*exp(lam(+1))*(exp(r(+1))+1-delt)=0;
 exp(w)=exp(a)*exp(k(-1))^alp*exp(h)^(1-alp)*(1-alp)/exp(h);
 exp(r)=exp(a)*exp(k(-1))^alp*alp/exp(k(-1))*exp(h)^(1-alp);
 exp(yy)=exp(a)*exp(k(-1))^alp*exp(h)^(1-alp);
exp(yy)-exp(c)-exp(xx)-exp(g)=0;
end;

 initval;

k= log(ks);  
c= log(cs);  
h= log(hs);  
xx= log(xxs);  
r= log(rs); 
w= log(ws);  
lam= log(lams);
yy= log(ys);
a =   0;
g =  log(gs);
  e = 0;
  u = 0;
end;

steady;
shocks;
var e = 0.008^2;
var u = 0.02^2;
end;

stoch_simul(dr_algo=0,periods=10000, irf=40, nocorr, nofunctions,  order=1) ;